EraGene Knowledge Graph

This repository contains the annotations used to build the EraGene knowledge graph. The database is provided as a Neo4j dump (Version 2026.06.0), which can be easily imported into a Neo4j instance.

Once imported, the database can be explored by querying it using the Cypher query language. The following sections provide instructions and examples for interacting with the database.

Requeriments

• Download and install Neo4j for Desktop 2.2.1 or later here.
• Create an instance if none is available.

Getting started

Download the Dump File

• Download the database dump file (eragene.dump).
• Save it to a suitable location on your local machine.

Prepare the Database

• Run Neo4j Desktop.
• Stop the instance if it is running (important).
• Identify the path where the instance is stored.

Example for windows:

Path = C:\Users\user\.Neo4jDesktop2\Data\dbmss\dbms-xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxxx

Load the Database

Run the following command to load the dump file and populate the database.

{Path}/bin/neo4j-admin database load neo4j --from-path=/path/to/dump/eragene.dump --overwrite-destination=true

Replace {Path} with the path to your Neo4j instance's directory.

If no errors occur, the database has been successfully imported.

Database Structure

General Schema of Relationships Between Labels

The relationships between node labels are represented in the following figure.

CALL db.schema.visualization();

Node Properties

The nodes that constitute the graph database are described in the following table.

MATCH (n)
UNWIND labels(n) AS label
UNWIND keys(n) AS key
RETURN label,
       key AS property,
       collect(DISTINCT valueType(n[key])) AS types
ORDER BY label, property;

Relationships

The relationships that connect the nodes in the database are the following.

MATCH (a)-[r]->(b)
RETURN DISTINCT
       labels(a) AS source_labels,
       type(r) AS relationship,
       labels(b) AS target_labels
ORDER BY relationship, source_labels, target_labels;

Usage Examples

Metabolites in the Database

MATCH (m:Compound)
RETURN 
  m.pk AS ID,
  m.html_name AS Name;

...

L-Tryptophan Production Levels Across Different Strains

MATCH (s:Strain)-[:PRODUCES]->(p:Production)-[ :TARGET]->(c:Compound {html_name:"L-tryptophan"})
RETURN
  s.name AS Strain,
  p.production AS Production,
  p.production_units AS Units,
  p.fermentation AS Scale,
  c.html_name AS Metabolite;

...

Genetic Modifications Introduced into Strains to Enhance L-Tryptophan Production

MATCH (tryptophan:Compound {html_name: "L-tryptophan"})
MATCH (tryptophan)<-[:TARGET]-(prod:Production {main:TRUE})
MATCH (prod)<-[:PRODUCES]-(strain:Strain)
MATCH (strain)-[:HAS_MODIFICATION]->(mod:Modification {exclusion : ''})
MATCH (mod)-[:AFFECT_GENE]->(gene:Gene)
RETURN DISTINCT 
    mod.modification_type AS modification_type,
    gene.name AS gene_name
ORDER BY gene.name, modification_type;