Recipes for computing radiation from a Kerr black hole using Generalized Sasaki-Nakamura formalism: I. Homogeneous solutions

for outgoing electromagnetic radiation with spin weight s=-1

s=-1;

Define some quantities for the Kerr black hole

M=1;
K=((r^2)+(a^2))*ω-m*a;
Δ=(r^2)-2*M*r+(a^2);
rp=M+(Sqrt[(M^2)-(a^2)]);
rm=M-(Sqrt[(M^2)-(a^2)]);
p=(ω-m*(a/(2*M*rp)));

Derivation of the Generalized Sasaki-Nakamura formalism

Homogeneous radial Teukolsky equation

VT=λ-4*I*s*ω*r-(((K^2)-2*I*s*(r-M)*K)/Δ);

RadialTeukolskyEq=(Δ^(-s))*D[(Δ^(s+1))*D[R[r],r],r]-VT*R[r];

Express R'' in terms of R and R' using the radial Teukolsky equation. This should give R'' = (VT/Δ)R - ((2(s+1)(r-M))/Δ)R'

Rprimeprime=R''[r]/.Solve[RadialTeukolskyEq==0,R''[r]][[1]][[1]];

Generalized Sasaki-Nakamura transformation

Transforming Teukolsky function R(r) to intermediate function χ(r)

Define two differential operators (SubPlus[J]) and (SubMinus[J]) which are

Jplus=D[#,r]+I*(K/Δ)*#&;
Jminus=D[#,r]-I*(K/Δ)*#&;

For s < 0, the transformation from Teukolsky radial function R to χ can be written as (setting (Subscript[g, 0])(r)=(((r^2)+(a^2))/(r^2)), (Subscript[g, 1])(r) = 1)

χ=((((Sqrt[((r^2)+(a^2))*Δ])))^(Abs[s]))*((((r^2)+(a^2))/(r^2)))*Jminus[(1)*(1/((((Sqrt[((r^2)+(a^2))])))^(Abs[s])))*R[r]]/.R''[r]->Rprimeprime;
Collect[χ,{R[r],R'[r]}]

Suppose that the transformation can also (in general) be written in the form of χ = α R + β (Δ^(s+1))R'. So we can extract what α and β should be

α=Simplify[Coefficient[χ,R[r]]]

β=Simplify[Coefficient[χ,R'[r]]*(Δ^(-(s+1)))]

Let us also compute their derivatives

αprime=Simplify[D[α,r]]

βprime=Simplify[D[β,r]]

Deriving the determinant η(r) of the transformation matrix from χ(r) to R(r)

Show that η, the determinant of the transformation matrix from χ back to R, can be written in a compact form η(r) = (Subscript[c, 0])+(Subscript[c, 1])/r + (Subscript[c, 2])/(r^2)+(Subscript[c, 3])/(r^3)+(Subscript[c, 4])/(r^4)

η=Simplify[α*(α+βprime*(Δ^(s+1)))-β*(Δ^(s+1))*(αprime+β*VT*(Δ^s))]

ηprime=Simplify[D[η,r]];

Let us show explicitly the (Subscript[c, 0,1,2,3,4])coefficients

Coefficient[η,r,0]

Coefficient[η,r,-1]

Coefficient[η,r,-2]

Coefficient[η,r,-3]

Coefficient[η,r,-4]

Generalized Sasaki-Nakamura potentials

Deriving expressions for the GSN potentials

sF1=Simplify[((ηprime)/η)];

sU1=Simplify[VT+(1/(β*(Δ^s)))*(D[2*α+βprime*(Δ^(s+1)),r]-sF1*(α+βprime*(Δ^(s+1))))];

sG=Simplify[((r*Δ)/((((r^2)+(a^2)))^2))+((s*(r-M))/((r^2)+(a^2)))];

sGprime=Simplify[D[sG,r]];

sF=Simplify[((Δ*sF1)/((r^2)+(a^2)))]

sU=Simplify[((Δ*sU1)/((((r^2)+(a^2)))^2))+(((sG))^2)+((Δ*sGprime)/((r^2)+(a^2)))-((Δ*sG*sF1)/((r^2)+(a^2)))]

Verifying the short-ranged nature of sF(r) and sU(r)

sF(r -> ∞) ~ -(((Subscript[c, 1])/(Subscript[c, 0]))/(r^2))

Simplify[Series[sF,{r,∞,2}]]

sU(r -> ∞) ~ -(ω^2)+(const/(r^2))

Simplify[Series[sU,{r,∞,2}]]

sF(r -> (SubPlus[r])) ~ 0 + 𝒪(r - (SubPlus[r]))

Series[Simplify[sF/.r->rp+x],{x,0,2}]

sU(r -> (SubPlus[r])) ~ -(p^2) + 𝒪(r - (SubPlus[r]))

Simplify[FullSimplify[SeriesCoefficient[Series[Simplify[sU/.r->rp+x],{x,0,2}],0]-(-(p^2))]]

Conversion factors between the Teukolsky function and the GSN function

<<SpinWeightedSpheroidalHarmonics`

(C^trans)

Assume that R(r -> ∞) = (C^trans) ((e^(SubStar[iωr]))/(r^(2s+1))), and for s = -1, R(r) ~ (r^1)as r -> ∞. Therefore applying the inverse operator on the GSN function (Λ^(-1))((e^(SubStar[iωr]))) should give, to the leading order, (r^1)

Series[FullSimplify[(1/η)*((((α+βprime*(Δ^(s+1)))/(Sqrt[((r^2)+(a^2))*(Δ^s)]))-(β*(Δ^(s+1)))*D[(1/(Sqrt[((r^2)+(a^2))*(Δ^s)])),r])-((β*(Δ^(s+1)))/(Sqrt[((r^2)+(a^2))*(Δ^s)]))*((((r^2)+(a^2))/Δ))*(I*ω))],{r,∞,5}]

(B^inc)

Similarly assume that R(r -> ∞) = (B^inc) ((e^(-(SubStar[iωr])))/r), and so *independent of s*, R(r) ~ (1/r)as r -> ∞. Therefore applying the operator on the Teukolsky function Λ(((e^(-(SubStar[iωr])))/r)) should give (r^0)

Series[FullSimplify[(Sqrt[((r^2)+(a^2))*(Δ^s)])*(α*R+β*(Δ^(s+1))*(D[R,r]-R*I*ω*(((r^2)+(a^2))/Δ)))/.R->(r^(-1)),Δ>0],{r,∞,1}]

(C^inc)

Assume that R(r -> (SubPlus[r])) = (C^inc) (e^(SubStar[ipr])), and so *independent of s*, R(r) ~ const as r -> (SubPlus[r]) or equivalent when Δ -> 0. Therefore applying the inverse operator on the GSN function (Λ^(-1))((e^(SubStar[ipr]))) should give, to the leading order, (r^0)

horizonExpansionOutgoingDelta=FullSimplify[(1/η)*((((α+βprime*(Δ^(s+1)))/(Sqrt[((r^2)+(a^2))*(Δ^s)]))-(β*(Δ^(s+1)))*D[(1/(Sqrt[((r^2)+(a^2))*(Δ^s)])),r])-((β*(Δ^(s+1)))/(Sqrt[((r^2)+(a^2))*(Δ^s)]))*((((r^2)+(a^2))/Δ))*(+I*p)),Δ>0]/.r->1+(Sqrt[1-(a^2)+δ]);

SeriesCoefficient[Series[Simplify[horizonExpansionOutgoingDelta,δ>0],{δ,0,2}],0]

FullSimplify[%40/.(2-(a^2)+2 (Sqrt[1-(a^2)]))->(SubPlus[r])/.(Sqrt[1+(Sqrt[1-(a^2)])])->(Sqrt[ (SubPlus[r])])/.(Sqrt[1-(a^2)])->(SubPlus[r])-1]

%41/.λ->(SpinWeightedSpheroidalEigenvalue[s,m,m,a*ω]+(((a*ω))^2)-2*m*a*ω)/.(SubPlus[r])->rp/.a->0.69/.ω->0.5/.m->2

((-(Sqrt[(SubPlus[r])])((a m - 4ω)(SubPlus[r])+2 (a^2) ω))/((Sqrt[2]) (a m-I λ)))/.λ->(SpinWeightedSpheroidalEigenvalue[s,m,m,a*ω]+(((a*ω))^2)-2*m*a*ω)/.(SubPlus[r])->rp/.a->0.69/.ω->0.5/.m->2

(B^trans)

Assume that R(r -> (SubPlus[r])) = (B^trans)  (Δ^(-s ))(e^(-(SubStar[ipr]))), and so for s = -1, R(r) ~ (Δ^1) as r -> (SubPlus[r]). Therefore applying the operator on the Teukolsky function Λ( (Δ^(-s ))(e^(-(SubStar[ipr])))) should give, to the leading order, (r^0)

Series[FullSimplify[(Sqrt[((r^2)+(a^2))*(Δ^s)])*(α*(Δ^(-s))+β*(-s*D[Δ,r]+((r^2)+(a^2))*(-I*p))),Δ>0],{r,rp,2}]

SeriesCoefficient[(1/(%44)),0]/.a->0.69/.ω->0.5/.m->2

(((SubPlus[r])^(3/2))/(4(Sqrt[2])))((((1+I a m - 4 I ω) (SubPlus[r])-(a^2)(1-2 I ω)))^(-1))/.(SubPlus[r])->rp/.a->0.69/.ω->0.5/.m->2

Transformation matrix from GSN function (X, dX/(SubStar[dr])) to Teukolsky function (R, dR/dr)

χtoRmat=Simplify[(1/η)*{{α+βprime*(Δ^(s+1)),-β*(Δ^(s+1))},{-(αprime+β*VT*(Δ^s)),α}}]

Xtoχmat=Simplify[{{(1/(Sqrt[((r^2)+(a^2))*(Δ^s)])),0},{D[(1/(Sqrt[((r^2)+(a^2))*(Δ^s)])),r],(1/(Sqrt[((r^2)+(a^2))*(Δ^s)]))}}]

XrstartoXrmat={{1,0},{0, (((r^2)+(a^2))/Δ)}}

overallmat=Simplify[χtoRmat . Xtoχmat.XrstartoXrmat ]

Asymptotic solutions to the Generalized Sasaki-Nakamura equation

Near infinity (r -> ∞)

Outgoing mode (~ (e^(SubStar[iωr])))

Explicit calculation

Let us assume that X((SubStar[r])) = exp((SubStar[iωr])) [1 + ((Subscript[f, 1])/(ωr))+((Subscript[f, 2])/(((ωr))^2))+((Subscript[f, 3])/(((ωr))^3))+...]

ODEInfOut=Simplify[f''[r]+((((r^2)+(a^2))/Δ))*(D[((Δ/((r^2)+(a^2)))),r]+2*I*ω-sF)*f'[r]+((((((r^2)+(a^2))/Δ)))^2)*(-(ω^2)-I*ω*sF-sU)*f[r]];

SeriesExpansionInfOut=Series[ODEInfOut/. f->Function[{r},1+((Subscript[f, 1])/((ω*r)))+((Subscript[f, 2])/(((ω*r))^2))+((Subscript[f, 3])/(((ω*r))^3))],{r,∞,4}];

AnsatzInfOutSoln=Simplify[Solve[{SeriesCoefficient[SeriesExpansionInfOut,1]==0,SeriesCoefficient[SeriesExpansionInfOut,2]==0,SeriesCoefficient[SeriesExpansionInfOut,3]==0,SeriesCoefficient[SeriesExpansionInfOut,4]==0},{(Subscript[f, 1]),(Subscript[f, 2]),(Subscript[f, 3])}][[1]]]

Formal series expansion

PpI=Simplify[((((r^2)+(a^2))/Δ))*(D[(Δ/((r^2)+(a^2))),r]+2*I*ω-sF),Δ>0];

QpI=Simplify[((((((r^2)+(a^2))/Δ)))^2)*(-(ω^2)-I*ω*sF-sU)];

PpIz=Simplify[PpI/.r->(1/z)]

PpIzRefined=Simplify[PpIz/.((a^2)+(1/(z^2)))->((((z^2)*(a^2)+1))/(z^2))/.((a^2)+((1-2 z)/(z^2)))->((((z^2)*(a^2)+1-2 z))/(z^2))]

Series[PpIzRefined,{z,0,2}]

QpIz=Simplify[QpI/.r->(1/z)]

Series[QpIz,{z,0,3}]

Ingoing mode (~ (e^(-(SubStar[iωr]))))

Explicit calculation

Let us assume that X((SubStar[r])) = exp(-(SubStar[iωr])) [1 + ((Subscript[g, 1])/(ωr))+((Subscript[g, 2])/(((ωr))^2))+((Subscript[g, 3])/(((ωr))^3))+...]

ODEInfIn=Simplify[g''[r]+((((r^2)+(a^2))/Δ))*(D[((Δ/((r^2)+(a^2)))),r]-2*I*ω-sF)*g'[r]+((((((r^2)+(a^2))/Δ)))^2)*(-(ω^2)+I*ω*sF-sU)*g[r]];

SeriesExpansionInfIn=Series[ODEInfIn/. g->Function[{r},1+((Subscript[g, 1])/((ω*r)))+((Subscript[g, 2])/(((ω*r))^2))+((Subscript[g, 3])/(((ω*r))^3))],{r,∞,4}];

AnsatzInfInSoln=Simplify[Solve[{SeriesCoefficient[SeriesExpansionInfIn,1]==0,SeriesCoefficient[SeriesExpansionInfIn,2]==0,SeriesCoefficient[SeriesExpansionInfIn,3]==0,SeriesCoefficient[SeriesExpansionInfIn,4]==0},{(Subscript[g, 1]),(Subscript[g, 2]),(Subscript[g, 3])}][[1]]]

Formal series expansion

PmI=Simplify[((((r^2)+(a^2))/Δ))*(D[(Δ/((r^2)+(a^2))),r]-2*I*ω-sF),Δ>0];

QmI=Simplify[((((((r^2)+(a^2))/Δ)))^2)*(-(ω^2)+I*ω*sF-sU)];

PmIz=Simplify[PmI/.r->(1/z)]

PmIzRefined=Simplify[PmIz/.((a^2)+(1/(z^2)))->((((z^2)*(a^2)+1))/(z^2))/.((a^2)+((1-2 z)/(z^2)))->((((z^2)*(a^2)+1-2 z))/(z^2))]

Series[PmIzRefined,{z,0,2}]

QmIz=Simplify[QmI/.r->(1/z)]

Series[QmIz,{z,0,3}]

Near horizon (r -> (SubPlus[r]))

Outgoing mode (~ (e^(SubStar[ipr])))

Explicit calculation

Let us assume that X((SubStar[r])) = exp((SubStar[ipr])) [1 + (Subscript[F, 1])(r-(SubPlus[r]))+(((Subscript[F, 2])(r-(SubPlus[r])))^2)+(((Subscript[F, 3])(r-(SubPlus[r])))^3)+...]

ODEHorOut=Simplify[F''[r]+((((r^2)+(a^2))/Δ))*(D[((Δ/((r^2)+(a^2)))),r]+2*I*p-sF)*F'[r]+((((((r^2)+(a^2))/Δ)))^2)*(-(p^2)-I*p*sF-sU)*F[r]];

SeriesExpansionHorOut=Series[ODEHorOut/. F->Function[{r},1+(Subscript[F, 1])*(r-rp)+(Subscript[F, 2])*(((r-rp))^2)+(Subscript[F, 3])*(((r-rp))^3)],{r,rp,4}]

HorFsoln=Solve[{SeriesCoefficient[SeriesExpansionHorOut,-1]==0,SeriesCoefficient[SeriesExpansionHorOut,0]==0,SeriesCoefficient[SeriesExpansionHorOut,1]==0},{(Subscript[F, 1]),(Subscript[F, 2]),(Subscript[F, 3])}]

Formal series expansion

PpH=Simplify[((((r^2)+(a^2))/(r-rm)))*(D[(Δ/((r^2)+(a^2))),r]+2*I*p-sF),Δ>0];

QpH=Simplify[((((((r^2)+(a^2))/(r-rm))))^2)*(-(p^2)-I*p*sF-sU)];

Simplify[PpH/.r->rp+x]

Simplify[QpH/.r->rp+x]

Check that the explicit calculation and the formal series expansion agree

-((SeriesCoefficient[Series[QpH,{r,rp,1}],1])/(SeriesCoefficient[Series[PpH,{r,rp,0}],0]))/.λ->(SpinWeightedSpheroidalEigenvalue[s,m,m,a*ω]+(((a*ω))^2)-2*m*a*ω)/.a->0.69/.ω->0.5/.m->2

((Subscript[F, 1])/.HorFsoln[[1]])/.λ->(SpinWeightedSpheroidalEigenvalue[s,m,m,a*ω]+(((a*ω))^2)-2*m*a*ω)/.a->0.69/.ω->0.5/.m->2

Ingoing mode (~ (e^(-(SubStar[ipr]))))

Explicit calculation

Let us assume that X((SubStar[r])) = exp(-(SubStar[ipr])) [1 + (Subscript[G, 1])(r-(SubPlus[r]))+(((Subscript[G, 2])(r-(SubPlus[r])))^2)+(((Subscript[G, 3])(r-(SubPlus[r])))^3)+...]

ODEHorIn=Simplify[G''[r]+((((r^2)+(a^2))/Δ))*(D[((Δ/((r^2)+(a^2)))),r]-2*I*p-sF)*G'[r]+((((((r^2)+(a^2))/Δ)))^2)*(-(p^2)+I*p*sF-sU)*G[r]];

SeriesExpansionHorIn=Series[ODEHorIn/. G->Function[{r},1+(Subscript[G, 1])*(r-rp)+(Subscript[G, 2])*(((r-rp))^2)+(Subscript[G, 3])*(((r-rp))^3)],{r,rp,4}]

HorGsoln=Solve[{SeriesCoefficient[SeriesExpansionHorIn,-1]==0,SeriesCoefficient[SeriesExpansionHorIn,0]==0,SeriesCoefficient[SeriesExpansionHorIn,1]==0},{(Subscript[G, 1]),(Subscript[G, 2]),(Subscript[G, 3])}]

Formal series expansion

PmH=Simplify[((((r^2)+(a^2))/(r-rm)))*(D[(Δ/((r^2)+(a^2))),r]-2*I*p-sF),Δ>0];

QmH=Simplify[((((((r^2)+(a^2))/(r-rm))))^2)*(-(p^2)+I*p*sF-sU)];

Simplify[PmH/.r->rp+x]

Simplify[QmH/.r->rp+x]

Check that the explicit calculation and the formal series expansion agree

-((SeriesCoefficient[Series[QmH,{r,rp,1}],1])/(SeriesCoefficient[Series[PmH,{r,rp,0}],0]))/.λ->(SpinWeightedSpheroidalEigenvalue[s,m,m,a*ω]+(((a*ω))^2)-2*m*a*ω)/.a->0.69/.ω->0.5/.m->2

((Subscript[G, 1])/.HorGsoln[[1]])/.λ->(SpinWeightedSpheroidalEigenvalue[s,m,m,a*ω]+(((a*ω))^2)-2*m*a*ω)/.a->0.69/.ω->0.5/.m->2