Deterministic Benefit of Amitosis

Model of amitosis

We model the change in the number of mutant alleles k at a single locus in a population as a result of selection, mutation and reproduction by mitosis.

Parameters

(Subscript[f, k]), frequency of genotype with k mutations
(OverBar[w]), mean fitness
(OverHat[w]), mean fitness at equilibrium
s, effect of a mutation if present in n copies (s < 0 if mutations are deleterious)
n, ploidy
u, mutation rate per locus (haploid)

Statistics

Genotype frequencies

f[n_]:=Table[(Subscript[f, k]),{k,0,n}]

cum[n_]:=1-(∑_(k=0)^(n-1))(Subscript[f, k])

Fitness

w[n_,s_]:=Table[1+((s k)/n),{k,0,n}]

Mean fitness

(OverBar[w])[n_,s_]:=Total[f[n]w[n,s]]

Evolutionary mechanisms

Natural selection

sel[n_,s_]:=((f[n]w[n,s])/((OverBar[w])[n,s]))-f[n]

Mutation

We assume that an individual can, at most, acquire one mutation.

mut[n_,u_]:=Flatten[{0,Table[u(n-k),{k,0,n-1}]f[n-1]}]-Table[u(n-k),{k,0,n}]f[n]

Amitosis

The probability that an individual containing k mutant alleles and n–k wildtype alleles will produce an offspring containing x mutant alleles is given by the hypergeometric distribution (Schensted 1958).

p[x_,k_,n_]:=PDF[HypergeometricDistribution[n,2k,2n],x]

q[k_,n_]:=Table[p[x,k,n],{x,0,n}]

amit[n_]:=Total[Table[q[k,n],{k,0,n}]f[n]]-f[n]

Combined effects of selection, mutation, and amitosis

Equation 3

delta[n_,s_,u_]:=sel[n,s]+mut[n,u]+amit[n]

Numerical calculations

Define composition of a population.

pass[x_]:=Module[{n=Length[x]},
Table[(Subscript[f, k])->x[[k+1]],{k,0,n-1}]
]

Unmutated population with ploidy n.

unmut[n_]:=Flatten[{1,Table[0,{k,1,n}]}]

Population evenly distributed between 0, 1, ..., n alleles.

even[n_]:=Table[(1./(n+1)),{k,0,n}]

Evolve over one generation

iter[x_,s_,u_]:=Module[{n=Length[x]-1},
x+delta[n,s,u]/.pass[x]
]

Evolve over t generations

evol[t_,x_,s_,u_]:=Module[{n=Length[x]-1,i=0,y=x},
While[i<t,y=iter[y,s,u];i++];
y
]

Evolve to equilibrium

equil[x_,s_,u_,ϵ_]:=Module[{n=Length[x]-1,t=0,y=x,nexty=x+1},
While[EuclideanDistance[y,nexty]>ϵ,y=nexty;nexty=iter[y,s,u];
t++];
(*Print[{n,s,u,t}];*)
nexty
]

Calculate mean fitness at equilibrium

Evolve to equilibrium starting from an unmutated population.

(OverHat[w])[n_,s_,u_,ϵ_]:=Module[{x=unmut[n],y},
y=equil[x,s,u,ϵ];
(OverBar[w])[n,s]/.pass[y]
]

Benefit of amitosis

Figure 2A: Effect of the genomic deleterious mutation rate. 
    (Note: the figures in the paper used more intermediate ploidies.)

ploidies=Table[(2^i),{i,1,7}]

U=.1;L=100;s=-.1;
wmit=((((1/(1+U/L))))^L);ben1=Table[{n,100((((OverHat[w])[n,s,U/(n L),(10^(-6))])^L)/wmit-1)},{n,ploidies}];

U=.2;
wmit=((((1/(1+U/L))))^L);ben2=Table[{n,100((((OverHat[w])[n,s,U/(n L),(10^(-6))])^L)/wmit-1)},{n,ploidies}];

ListLogLinearPlot[{ben1,ben2},Joined-> True,Frame->True,FrameLabel->{"Ploidy (n)","Benefit of amitosis (%)"},PlotRange->{-1,21},FrameTicks->{{{0,5,10,15,20},None},{ploidies,None}},PlotLegends->Placed[{"(Subscript[U, d]) = 0.1","(Subscript[U, d]) = 0.2"},Above],AspectRatio->.75,BaseStyle->Medium]

Figure 2B: Effect of the selection coefficient of a deleterious mutation. 
    (Note: the figures in the paper used more intermediate ploidies.)

U=.1;L=100;s=-.01;
wmit=((((1/(1+U/L))))^L);ben3=Table[{n,100((((OverHat[w])[n,s,U/(n L),(10^(-6))])^L)/wmit-1)},{n,ploidies}];

s=-.5;
wmit=((((1/(1+U/L))))^L);ben4=Table[{n,100((((OverHat[w])[n,s,U/(n L),(10^(-6))])^L)/wmit-1)},{n,ploidies}];

ListLogLinearPlot[{ben1,ben3,ben4},Joined-> True,Frame->True,FrameLabel->{"Ploidy (n)","Benefit of amitosis (%)"},PlotRange->{-1,21},FrameTicks->{{{0,5,10,15,20},None},{ploidies,None}},PlotLegends->Placed[{"(Subscript[s, d]) = -0.1","(Subscript[s, d]) = -0.01","(Subscript[s, d]) = -0.5"},Above],AspectRatio->.75,BaseStyle->Medium]