Needs["IGraphM`"];

Communities at different scales

A Sierpinski graph, convert from a geometrical mesh object with IGraph/M’s facilities:

g=IGMeshGraph[SierpinskiMesh[3],GraphStyle->"BasicBlack",VertexSize->0.5]

A bigger version of the same:

g=IGMeshGraph[SierpinskiMesh[5],GraphStyle->"BasicBlack",VertexSize->0.9];
Table[Rasterize@HighlightGraph[g,IGCommunitiesMultilevel[g,"Resolution"->γ]["Communities"]],{γ,{1/100,1/10,1,5}}]

gr=IGMeshGraph[SierpinskiMesh[5],GraphStyle->"BasicBlack",VertexSize->0.9,PerformanceGoal->"Speed"];
Manipulate[
SeedRandom[137];
HighlightGraph[
  gr,
  IGCommunitiesLeiden[gr, "Resolution" -> 2^α]["Communities"]
 ],
 {α,-7,6}
]

Clique percolation

g=IGGiantComponent@ExampleData[{"NetworkGraph","CondensedMatterCollaborations2005"}];
{VertexCount[g],EdgeCount[g]}

SeedRandom[42];
subset=IGRandomWalk[g,RandomChoice@VertexList[g],300];
sg=IGLayoutGraphOpt@Subgraph[g,subset]

cliquePerc[g_?GraphQ,k_Integer?Positive]:=
Union@@@ConnectedComponents@RelationGraph[
Length@Intersection[##]≥(k-1)&,
IGCliques[g,{k}]
]

Manipulate[
HighlightGraph[sg,Subgraph[sg,#]&/@cliquePerc[sg,k]],
{{k,4},2,6,1}
]