Presentation figures

Graph theory

PetersenGraph[GraphStyle->"ThickEdge",EdgeStyle->Opacity[2/3]]//IGEdgeMap[ColorData[112],EdgeStyle->(First@IGKEdgeColoring[#,4]&)]

g=GraphData["GreatRhombicuboctahedralGraph"];
Graph[g,GraphLayout->"SpectralEmbedding",VertexSize->0.6,GraphStyle->"BasicBlack",EdgeStyle->Directive[AbsoluteThickness[8],Opacity[0.8]]]//IGEdgeMap[ColorData[112],EdgeStyle->(IGPartitionsToMembership[LineGraph[g]]@*GroupOrbits@*IGBlissAutomorphismGroup@*LineGraph)]

g=Nest[IGMycielskian,IGEmptyGraph[1],3];
Graph[g,GraphLayout->"SpectralEmbedding",VertexSize->0.35,GraphStyle->"BasicBlack",EdgeStyle->Thick]//IGVertexMap[ColorData[97],VertexStyle->(IGPartitionsToMembership[g]@*GroupOrbits@*IGBlissAutomorphismGroup)]

With[{g=GraphData[{"Mycielski",4}]},HighlightGraph[g,GroupOrbits@IGBlissAutomorphismGroup[g],VertexSize->Large,PlotTheme->"BasicBlack",EdgeStyle->Blue]]

Network science

SeedRandom[12345];
g=ExampleData[{"NetworkGraph","AstrophysicsCollaborations"}];
g=Subgraph[g,IGRandomWalk[g,RandomChoice@VertexList@IGGiantComponent[g],200,EdgeWeight->None],GraphStyle->"BasicBlack",EdgeStyle->Opacity[0.5],GraphLayout->{"SpringElectricalEmbedding","RepulsiveForcePower"->-3,"SpringConstant"->2}]

IGEdgeProp[EdgeWeight][g]//Log//MinMax

g2=g//IGVertexMap[7(Sqrt[#])&,VertexSize->IGCloseness]//IGEdgeMap[AbsoluteThickness[(1.3-Log[#])0.3]&,EdgeStyle->IGEdgeProp[EdgeWeight]]

cm=IGCommunitiesLeiden[g]["Communities"];

commEdges=Join@@(EdgeList@Subgraph[g,#]&)/@cm;

HighlightGraph[HighlightGraph[g2,cm],Style[Complement[EdgeList[g],commEdges],Dashed],ImageSize->Large]

Export for Python

SetDirectory@NotebookDirectory[]

IGExport["les-miserables.graphml",ExampleData[{"NetworkGraph","LesMiserables"}],"GraphML"]