# Define classes

#############################################
## A definition of Old Chinese phonology ##
#############################################

define OCOBSTRUENTSB [
  b:{*b} | p:{*p} | {pʰ}:{*pʰ} | 
  d:{*d} | t:{*t} | {tʰ}:{*tʰ} | 
  g:{*g} | k:{*k} | {kʰ}:{*kʰ} | 
  ɢ:{*ɢ} | q:{*q} | {qʰ}:{*qʰ} |
  {gʷ}:{*gʷ} | {kʷ}:{*kʷ} | {kʷʰ}:{*kʷʰ} |
  {ɢʷ}:{*ɢʷ} | {qʷ}:{*qʷ} | {qʰʷ}:{*qʰʷ} |
  {dz}:{*dz} | {ts}:{*ts} | {tsʰ}:{*tsʰ} | 
  s:{*s} |
  ʔ:{*ʔ} ];

define OCVOICEDRESONANTSB [
  m:{*m} | n:{*n} | ŋ:{*ŋ} | {ŋʷ}:{*ŋʷ} | r:{*r} | l:{*l} ];

define OCVOICEDRESONANTSNOTRB [
  m:{*m} | n:{*n} | ŋ:{*ŋ} | {ŋʷ}:{*ŋʷ} | l:{*l} ];

define OCVOICELESSRESONANTSB [
  {m̥}:{*m̥} | {n̥}:{*n̥} | {ŋ̊}:{*ŋ̊} | {ŋ̊ʷ}:{*ŋ̊ʷ} | {r̥}:{*r̥} | l̥:{*l̥} ];

define OCMINORSYLLALBE [
  {tə}:{*tə} | {kə}:{*kə} | {pə}:{*pə} | {mə}:{*mə} | {sə}:{*sə} ];

define OCPREFIX [ {t}:{*t} | {k}:{*k} | {p}:{*p} | {m}:{*m} | {s}:{*s} ];

define OCRESONANTSB [OCVOICEDRESONANTSB|OCVOICELESSRESONANTSB];

define OCINITIALB [OCOBSTRUENTSB|OCRESONANTSB];

define OCINITIALA OCINITIALB ˤ ; 

define OCMEDIAL r:{*r} ;

define OCNUCLEUS [ a:{*a} | ᴀ:{*ᴀ} | e:{*e} | i:{*i} | o:{*o} | u:{*u} | ə:{*ə} ];
# I am including a 7th vowel, ᴀ to index, as Baxter 1992 did, two different pathways of 
# development for the vowel -a-, which are in need of further investigation.

define OCCODA [j:{*j}|t:{*t}|p:{*p}|k:{*k}|n:{*n}|r:{*r}|m:{*m}|ŋ:{*ŋ}|w:{*w}|{wk}:{*wk}];

define OCTONE [s:{*s}|ʔ:{*ʔ}];

define OCSYLLABLEA (OCPREFIX|OCMINORSYLLALBE) OCINITIALA (OCMEDIAL) OCNUCLEUS (OCCODA) (OCTONE) ;  

define OCSYLLABLEB (OCPREFIX|OCMINORSYLLALBE) OCINITIALB (OCMEDIAL) OCNUCLEUS (OCCODA) (OCTONE) ; 

define OCSYLLABLE [OCSYLLABLEA|OCSYLLABLEB] ;

##################################################################
## Some sound classes that are useful for stating sound changes ##
##################################################################

define OCLABIOVELARS [{*kʷ}|{*kʷʰ}|{*gʷ}|{*ŋʷ}|{*ŋ̊ʷ}];
define OCFRONTVOWEL [{*e}|{*i}];
define BILABIAL [{*p}|{*pʰ}|{*b}|{*m}];
define ACUTEONSET [{*ts}|{*tsʰ}|{*t}|{*d}|{*n}|{*j}|
{*tʃ}|{*tʃʰ}|{*dʒ}|{*ɲ}|{*s}];
define ACUTECODA [{*t}|{*n}|{*j}|{*r}];
# Because s counts as an acute onset but not as an acute coda, we need to distinguish
# the two classes.
define VELAR [{*k}|{*g}|{*kʰ}|{*ŋ}];
define GRAVE [VELAR|BILABIAL];
define NASAL [{*m}|{*n}|{*ŋ}];
define RETROFLEX [{*ʈ}|{*ʈʰ}|{*ɖ}|{*ʂ}];
define VOWEL [{*a}|{*ᴀ}|{*e}|{*i}|{*o}|{*u}|{*ə}|{*æ}|{*ɛ}|{*ʌ}|{*ɔ}|{*ɨ}];

##################
## Book Keeping ##
##################

# Asterisk utilities
define RemoveAsterisks {*} -> 0;
define RejectAsterisks [¬ [? * "*" ? *]];

##############################
## The Historical Phonology ##
##############################

##  Early Old Chinese to Late Old Chinese

## Phonotactic reanalysis
define EarlyOChi·Phonotactic·reanaysis {*t*s} -> {*ts} || .#. _ ; 

##  Late Old Chinese to Han Chinese

## Transducer for Type B syllables 

### A.9. Rounding dissimilation
define LateOChi·RoundingDissimilationB {*u} -> {*ə} || OCLABIOVELARS ({*r}) _ ; 

### Loss of labio-velars (Type B) 
define LateOchiLabiovelarLossBmain
   {*kʷ} -> {*k*w} , 
   {*kʷʰ} -> {kʰ*w} , 
   {*gʷ} -> {*g*w} , 
   {*ŋʷ} -> {*ŋ*w} ;
define LateOchiLabiovelarLossBcleanup
   {*w*r} -> {*r*w} || _ OCNUCLEUS ;
define LateOchiLabiovelarLossB
   LateOchiLabiovelarLossBmain .o.
   LateOchiLabiovelarLossBcleanup
   ;

###  Initiat cluster simplification (Type B)
define LateOChi·ClusterSimpB {*s} OCVOICEDRESONANTSNOTRB -> {*s} ||  _ ({*r}) ({*w}) OCNUCLEUS ;

### A 01. -ps to -ts (Baxter 1992: Appendix, 565-566) (Type B)
define LateOChi·PS⇒TSB {*p*s} -> {*t*s} || _ .#. ;

### A.2. *P(r)o > *P(r)ə  (Type B)
define LateOChi·Po⇒PəB {*o} -> {*ə} || BILABIAL ({*r}) _ ;

### A 03. Rounding dipthongization (Baxter 1992: 566-567) (Type B)
define LateOChi·RoundingDipthongizationo⇒waB {*o} -> {*w*a} || _ ACUTECODA ;
define LateOChi·RoundingDipthongizationu⇒wəB {*u} -> {*w*ə} || _ ACUTECODA ;
define LateOChi·RoundingDipthongizationCleanupB {*w*w} -> {*w} || _ OCNUCLEUS ; 
define LateOChi·RoundingDipthongizationB
      LateOChi·RoundingDipthongizationo⇒waB .o.
      LateOChi·RoundingDipthongizationu⇒wəB .o.
      LateOChi·RoundingDipthongizationCleanupB
      ;

### A.4. *w-neutralization
define LateOChi·wneutralizationB [..] -> {*w} || BILABIAL ({*r}) _ OCNUCLEUS  ;

### A.5. Labial neutralization
define LateOChi·LabialNeutralizationB {*u} -> {*ə}, {*o} -> {*a} || _ BILABIAL ;

## a-backing
## This is a bookkeeping rule, we need a to back to feed Schuessler's formulation of vowel warping
define LateOchia⇒ɑ {*a} -> {*ɑ};

## Schuessler's vowel warping (Schuessler 2006)
## Vowel warping part 1
### Type B fronting 
define LateOChi·VowelWarp1B
 {*i} -> {*j*i},
 {*e} -> {*j*e},
 {*ə} -> {*j*ə},
 {*ɑ} -> {*ɰ*ɑ},
 {*o} -> {*ɰ*o},
 {*ə*j} -> {*ɨ*j};

define LateOChi·VowelWarp1A
 {*u} -> {*o*w},
#Baxter sees this next one as part of hi > mid
 {*i} -> {*e*j}, 
 {*ɑ*w} -> {*e*w};

###Schuessler presents there as being a second wave of vowe warping later, that gives us these changes. 
define LateOChi·VowelWarp2A
 {*e} -> {*e*j},
 {*ə} -> {*ɑ*j},
 {*ɑ} -> {*ɔ};

define LateOChi·VowelWarp2B
 {*e} -> {*e*j},
 {*j*ə} -> {*ɨ},
 {*ɑ} -> {*ɔ};
### There are a few other changes that he doesn't mention, which I assume come out in the wash somehow, so I omit. 

### I have the impression that this formulation of vowel warping makes Baxter's A.26. j-insertion (Type A) 
### and  A.13. *-u(K) > -aw(K) (Type A) redundant. We still need A.28. *j-backing but for a much more limited
### purpose.

### A.28. *j-backing
define LateOChi·jBacking·j⇒ɰB {*j} -> {*ɰ} || {*r} ({*w}) _ ; 

### A.6. Final cluster simplification
define LateOChi·ks⇒sB {*k*s} -> {*s} || _ .#. ;
define LateOChi·wks⇒wsB {*wk*s} -> {*w*s} || _ .#. ;
define LateOChi·ts⇒jsB {*t*s} -> {*j*s} || _ .#. ;

### A. 7. Dental palatalization (Type B)
define LateOChi·dentalpalatalizationB 
   {*t} -> {*tʃ}, {*tʰ} -> {*tʃʰ}, {*d} -> {*dʒ}, {*n} -> {*ɲ} ||  _ ({*r}) ({*w}) [{*j}|{*ɰ}] ; 

### A.8. Velar palatalization (Type B)
define LateOChi·velarpalatalizationB 
   {*k} -> {*tʃ}, {*kʰ} -> {*tʃʰ}, {*g} -> {*dʒ}, {*ŋ} -> {*ɲ} ||  _ {*j} ; 

### A.l0. *-aj monophthongization (Type B)
define LateOChi·aj⇒æ {*ɑ*j} -> {*æ} || _ (OCTONE) .#. ; 

### A.ll. *-ᴀ(k) fronting (Type B)
define LateOChi·ᴀk⇒æKB {*ᴀ} -> {*æ}  || ACUTEONSET _ ({*k}) (OCTONE) .#. ; 

### A.12. *-a > -ʌ (Type B)
define LateOChi·a⇒ʌB {*ɑ} -> {*ʌ} || [ACUTEONSET|VELAR] {*ɰ} _ (OCTONE) .#. ;

### A.22. *-iw(k) > -uw(k) (Type B)
define LateOChi·iwk⇒uwk {*i*wk} -> {*u*wk} || _ (OCTONE) .#. ;
define LateOChi·iw⇒uw {*i*w} -> {*u*w} || ACUTEONSET ({*r}) ({*w}) {*j} _ (OCTONE) .#. ;

### A.21. *-wk > -k
define LateOChi·wk⇒kB {*wk} -> {*k} || [{*e}|{*a}]_ (OCTONE) .#. ;

### A.l4. *-o(K) > -uw(K) (Type A)
define LateOChi·oK⇒uwKA {*o} -> {*u*w} || _ (VELAR) (OCTONE) .#. ;

### A 20. Voiceless Resonant Loss (Type B) (Baxter 1992: 576)
define LateOChi·voicelessresonantlossB
   {*m̥} -> {*x}, {*ŋ̊} -> {*x}, {*l̥} -> {*ʃ}, {*n̥} -> {*ʃ}, {*r̥} -> {*tʰ*r} || _ ({*r}) ({*w}) ([{*j}|{*ɰ}]) VOWEL ;

### A 15. r-color (Baxter 1992: 543-544) (Type B)
define LateOChi·RcolorB
   {*ɑ} -> {*æ}, {*e} -> {*ɛ}, {*ə} -> {*ɛ} || r ({*w}) ([{*j}|{*ɰ}]) _ ;

### A.16. Acute fronting (type B)
define LateOChi·AcuteFrontinga⇒æB {*ɑ} -> {*æ} || ACUTEONSET _ ACUTECODA ;

### A.17. Rounding assimilation (type B)
define LateOChi·RoundingAssimilationə⇒uB {*ə} -> {*u} || GRAVE {*w} _ (VELAR) (OCTONE) .#. ;

### A 18. *-a > -u (type A)
define LateOChi·a⇒uA {*ɑ} -> {*u} || _ (OCTONE) .#. ;

### A.l9. Labial dissimilation
define LateOChi·LabialDissimilationəm⇒əŋ {*ə*m} -> {*ə*ŋ} || GRAVE ({*r}) {*w} _ (OCTONE) .#. ;

### A.23. *ə-fronting
define LateOChi·JəfrontingB {*ə} -> {*i} || ACUTE _ ACUTE ;


### A.24. Hi > mid (Type A)
define LateOChi·Hi⇒Midi⇒eA {*i} -> {*e} ; 
define LateOChi·Hi⇒Midi⇒eA {*ə} -> {*ʌ} ; 
define LateOChi·Hi⇒MidA
     LateOChi·Hi⇒Midi⇒eA .o.
     LateOChi·Hi⇒Midi⇒eA 
     ; 

### A.25. Qùshēng formation
define LateOChi·QùshēngB {*s} -> {*H} || _ .#. ;

### Shăngshēng formation
### Baxter seems not to have put this in his list. Not very profound. 
define LateOChi·ShăngshēngB {*ʔ} -> {*X} || _ .#. ;


### A.27. *a-raising (Type B)
define LateOChi·ARaisinga⇒ʌ {*ɑ} -> {*ʌ} || _ ACUTECODA ; 


###  Retroflection (Type B)
define LateOChi·tr⇒ʈB {*t*r} -> {*ʈ} ; 
define LateOChi·tr⇒ʈʰB {*tʰ*r} -> {*ʈʰ} ; 
define LateOChi·dr⇒ɖB {*d*r} -> {*ɖ} ; 
define LateOChi·sr⇒ʂB {*s*r} -> {*ʂ} ; 
define LateOChi·tsr⇒tʂB {*ts*r} -> {*tʂ} ; 
define LateOChi·tshr⇒tʂʰB {*tsʰ*r} -> {*tʂʰ} ; 
define LateOChi·RetroflexB
       LateOChi·tr⇒ʈB
   .o. LateOChi·tr⇒ʈʰB
   .o. LateOChi·dr⇒ɖB
   .o. LateOChi·tsr⇒tʂB 
   .o. LateOChi·tshr⇒tʂʰB
   .o. LateOChi·sr⇒ʂB
   ;

###  Initial r changes to l (Type B)
define LateOChi·r⇒lB {*r} -> {*l} || .#. _  ;

### A.29. *r-loss (Type B)
### By ordering this after initial r changes to l we do not have to specify that it only applies to medials. 
### There is going to be a better way to formulate this 
define LateOChi·MedialRLossB {*r}  -> 0 || ¬RETROFLEX _ ({*w}) ({*j}|{*ɰ}) VOWEL ;

### A.30. *-jɨ(K) > -i(K) (Type B)
define LateOChi·jɨK⇒-iKB {*ɨ} -> {*i} || {*j} _ VELAR ;

### A.31. TSrj- > TSr-
define LateOChi·TSrj⇒TSrB {*ɰ} -> 0, {*j} -> 0 || [{*ʂ}|{*tʂ}|{*tʂʰ}]  ({*w}) _ ;

### A.32. jɛ>je
### This is a minor change assumed in one analysis of the development of the chóngniu finals;
### for discussion see section 7.3.3.
define LateOChi·TSrj⇒TSrB {*ɰ} -> 0, {*j} -> 0 || [{*ʂ}|{*tʂ}|{*tʂʰ}]  ({*w}) _ ;

### A.33. mjuw(K) > muw(K)
### This is a minor change which deleted medial -j- from syllables beginning with the sequence
### mjuw-. It took place during the Middle Chinese period, and gives rise to a number of
### apparent irregularities. For example, the Guangyùn gives the reading muwH for
### (1914) 貿 [mào] < muwH < mjuwH < *m(r)us 'barter, exchange'.
### Normally, the Middle Chinese division-I final -uwH would reflect OC *-(r)o(k)s; but the
### reconstruction of *u in this word is supported by the rhyming of other words in the same
### phonetic series, such as
### (1915) 卯 mao < mrewX < *mruʔ 'cyclical sign (4th earthly branch)',
### which rhymes as *-uʔ in Ode 193.1A.

### Summing all changes to Han
define LateOChi·B
      OCSYLLABLEB
      .o. EarlyOChi·Phonotactic·reanaysis
      .o. LateOChi·RoundingDissimilationB
      .o. LateOchiLabiovelarLossB
      .o. LateOChi·ClusterSimpB
      .o. LateOChi·PS⇒TSB
      .o. LateOChi·RoundingDipthongizationB
      .o. LateOChi·wneutralizationB
      .o. LateOChi·LabialNeutralizationB
      .o. LateOchia⇒ɑ
      .o. LateOChi·VowelWarp1B
      .o. LateOChi·jBacking·j⇒ɰB
      .o. LateOChi·ks⇒sB
      .o. LateOChi·wks⇒wsB
      .o. LateOChi·ts⇒jsB
      .o. LateOChi·dentalpalatalizationB
      .o. LateOChi·velarpalatalizationB
      .o. LateOChi·aj⇒æ
      .o. LateOChi·ᴀk⇒æKB
      .o. LateOChi·a⇒ʌB
      .o. LateOChi·iwk⇒uwk
      .o. LateOChi·iw⇒uw
      .o. LateOChi·wk⇒kB
      .o. LateOChi·voicelessresonantlossB
      .o. LateOChi·RcolorB
      .o. LateOChi·AcuteFrontinga⇒æB
      .o. LateOChi·RoundingAssimilationə⇒uB
      .o. LateOChi·LabialDissimilationəm⇒əŋ
      .o. LateOChi·QùshēngB
      .o. LateOChi·ShăngshēngB
      .o. LateOChi·ARaisinga⇒ʌ
      .o. LateOChi·r⇒lB
      .o. LateOChi·JəfrontingB
      .o. LateOChi·RetroflexB
      .o. LateOChi·MedialRLossB
      .o. LateOChi·TSrj⇒TSrB 
      ; 

regex LateOChi·B
 ;

apply down tsrawk