//This macro divides all the images contained in a folder
//into 9 equal parts and saves them in another that the user
//must specify.
//The name of the split images ends in a two-digit code that
//indicates the position to which it corresponds:
//00 corresponds to the upper left corner,
//22 to the lower right corner 
//and 11 is the center position.

//RUN THIS MACRO FROM Plugins/Macros/Run


//batch directories;
dir1 = getDirectory("Choose source folder ");
dir2 = getDirectory("Choose the destination folder ");
list = getFileList(dir1);
aumento = getNumber("Indicate the magnification used (10/50)", 10);
print(aumento);
setBatchMode(true);

//Directoy loop start;
//This loop activates each image in the chosen folder;
for (i=0; i<list.length; i++) {
 showProgress(i+1, list.length);
 open(dir1+list[i]);


//Image Parameters ;
//In the "ventana" variable we save the title of the active image at that moment;
ventana = getTitle();
sizeW = getWidth();
sizeH = getHeight();
pasoW = round(sizeW/3);
pasoH = round(sizeH/3);
print("\\Clear");

//Calibrating;
//Before splitting every image we set the scale
if (aumento == 10) {
	run("Set Scale...", "distance=2.9475 known=1 unit=[micron ]");
} else {
	run("Set Scale...", "distance=14.72 known=1 unit=[micron ]");
}

//Splitting;
for (y = 0; y < 3; y++) {
for (x = 0; x < 3; x++) {
makeRectangle(pasoW*x, pasoH*y, pasoW, pasoH);
run("Duplicate...", " ");
carpeta = dir2;
Nventana=replace(ventana, ".tif", "_");
fichero = carpeta + Nventana + toString(x, 0) + toString(y, 0);
//print(fichero);
saveAs(".tif", fichero );
close();
selectWindow(ventana);
}}
run("Select None");

//Directoy loop end;
print(aumento);
close();
}