Needs["NDSolve`FEM`"]

This code produces the 3d rendering of an active wave and a passive wave. We set the elastic moduli in the dynamical matrix, then consider one of its eigenvectors as normal mode of the plate in the bulk. A plane wave is then constructed. Then, a 3d mesh of a plate is deformed according to the wave and a slice of it is coloured with a colormap that describes the transverse strains.

Passive wave

$Assumptions={B,μ1,μ2,K1,K2,q}∈Reals;
dynMatCart=(({{μ2 (qx^2+qy^2), -I(Sqrt[12])(μ2 qx-K2 qy), -I(Sqrt[12])(μ2 qy+K2 qx)}, {I(Sqrt[12])(μ2 qx+K2 qy), B qx^2+μ1(qx^2+qy^2)+12μ2, B qx qy+K1(qx^2+qy^2)+12K2}, {I(Sqrt[12])(μ2 qy-K2 qx), B qx qy-(K1(qx^2+qy^2)+12K2), B qy^2+μ1(qx^2+qy^2)+12μ2}}));

(dynMatSimplified=dynMatCart/.{B->1,μ1->0.3,μ2->0.3,K1->0,K2->0,qy->0,qx->2})//MatrixForm

eigenvectors=Normalize/@Eigenvectors[dynMatSimplified]
uq=eigenvectors[[1]]

q=2;
WaveW[x_,y_]:=Re[uq[[1]] Exp[I(q x )]]
WavePhiX[x_,y_]:=Re[uq[[2]] Exp[I(q x )]]
WavePhiY[x_,y_]:=Re[uq[[3]] Exp[I(q x )]]

DisplacementField[x_,y_,z_]:={z WavePhiX[x,y],z WavePhiY[x,y],WaveW[x,y]};
Deformation[{x_,y_,z_}]:={x,y,z}+0.7DisplacementField[x,y,z];

DerivativeX[x_,y_]:=Evaluate@D[ComplexExpand@WaveW[x,y],x]
StrainXZ[x_,y_]:=1/2( DerivativeX[x,y]+WavePhiX[x,y])
DerivativeY[x_,y_]:=Evaluate@D[ComplexExpand@WaveW[x,y],y];
StrainYZ[x_,y_]:=1/2(DerivativeY[x,y]+WavePhiY[x,y])
StrainWheel[x_,y_]:=Arg[StrainXZ[x,y]+I StrainYZ[x,y]];
NormalizedStrainWheel[x_,y_]:=(StrainWheel[x,y]+Pi)/(2Pi);
StrainModulus[x_,y_]:=Sqrt[StrainXZ[x,y]^2+StrainYZ[x,y]^2];

(* functions to construct the deformed mesh *)
ParallelepipedGenerator[l1_,l2_,l3_]:=Parallelepiped[{-l1/2,-l2/2,-l3/2},{{l1,0,0},{0,l2,0},{0,0,l3}}];
DeformedPlateGenerator[l1_,l2_,l3_]:=
Module[{region,mesh,deformedMesh,deformedRegion,plot},
region=ParallelepipedGenerator[l1,l2,l3];
mesh=ToElementMesh[region,MaxCellMeasure->0.003];
deformedMesh=ToElementMesh["Coordinates"->Map[Deformation,mesh["Coordinates"]],"MeshElements"->mesh["MeshElements"],
 "BoundaryElements"->mesh["BoundaryElements"], "PointElements"->mesh["PointElements"]];
deformedRegion=MeshRegion[deformedMesh];
Return[deformedRegion]
];

Construct the 3d object

defPlate=DeformedPlateGenerator[6Pi/q,7,0.7];
plate=RegionPlot3D[defPlate,
MeshShading->{{Automatic,None},{None,Automatic}},
Boxed->False,PlotStyle->Directive[Gray,Glow[],Opacity[0.2]]
];

defSlice=DeformedPlateGenerator[6Pi/q,0.1,0.75];
slice=RegionPlot3D[defSlice,MeshShading->{{Automatic,None},{None,Automatic}},ColorFunction->Function[Directive[Opacity[StrainModulus[#1,#2]*1.25],Hue[NormalizedStrainWheel[#1,#2]]]],
ColorFunctionScaling->False,Boxed->False,Lighting->"Neutral"];

plateAndSlice=Show[plate,slice]

defSmallPlate=DeformedPlateGenerator[6Pi/q,1.4,0.7];
smallPlate=RegionPlot3D[defSmallPlate,
MeshShading->{{Automatic,None},{None,Automatic}},
Boxed->False,PlotStyle->Directive[Gray,Glow[],Opacity[0.2]]
];

Show[smallPlate,slice,ViewPoint->Above]

Legend

RegionPlot[x^2+y^2<1,{x,-1,1},{y,-1,1},ColorFunction->Function[Directive[Opacity[Sqrt[#1^2+#2^2]],Hue[(Arg[#1+I #2]+Pi)/(2Pi)]]],ColorFunctionScaling->False,Frame->False]

Active wave

(*I want to plot Re(u_q (e^(Iqx))). Let's calculate u_q from the dynamical matrix *)
(* dynamical matrix *)
dynMatGeneral=(({{((qx^2)+(qy^2)) μ2, -I (-K2 qy+qx μ2), -I (K2 qx+qy μ2)}, {I (K2 qy+qx μ2), B (qx^2)+((qx^2)+(qy^2)) μ1+μ2, K2+B qx qy+K1 ((qx^2)+(qy^2))}, {I (-K2 qx+qy μ2), -K2+B qx qy-K1 ((qx^2)+(qy^2)), B (qy^2)+((qx^2)+(qy^2)) μ1+μ2}}));

(dynMat=dynMatGeneral/.{B->0,μ1->0.,μ2->0.})//MatrixForm

(* set the parameters *)
qx=2;
qy=0;
dynMatNum=dynMat/.{K1->0.,K2->1}

(* find the eigenvectors*)
eigenvectors=Normalize/@Eigenvectors[dynMatNum];
uq=eigenvectors[[2]]

(* calculate the waves for w, and the angles *)
WaveW[{x_,y_}]:=Re[uq[[1]] Exp[I(qx x + qy y)]];
WavePhiX[x_,y_]:=Re[uq[[2]] Exp[I(qx x + qy y)]];
WavePhiY[x_,y_]:=Re[uq[[3]] Exp[I(qx x + qy y)]];

(* plot the displacement field, as a vector field *)
DisplacementField[x_,y_,z_]:={z WavePhiX[x,y],z WavePhiY[x,y],WaveW[{x,y}]};

DerivativeX[x_,y_]:=Evaluate@D[ComplexExpand@WaveW[{x,y}],x]
StrainXZ[x_,y_]:=1/2( DerivativeX[x,y]+WavePhiX[x,y])
DerivativeY[x_,y_]:=Evaluate@D[ComplexExpand@WaveW[{x,y}],y]
StrainYZ[x_,y_]:=1/2(DerivativeY[x,y]+WavePhiY[x,y])
StrainWheel[x_,y_]:=Arg[StrainXZ[x,y]+I StrainYZ[x,y]]
NormalizedStrainWheel[x_,y_]:=(StrainWheel[x,y]+Pi)/(2Pi)
StrainModulus[x_,y_]:=Sqrt[StrainXZ[x,y]^2+StrainYZ[x,y]^2]

(* PLATE WITH MESH *)
Needs["NDSolve`FEM`"]

ParallelepipedGenerator[l1_,l2_,l3_]:=Parallelepiped[{-l1/2,-l2/2,-l3/2},{{l1,0,0},{0,l2,0},{0,0,l3}}];
f[{x_,y_,z_}]:={x,y,z}+0.7 DisplacementField[x,y,z];
DeformedPlateGenerator[l1_,l2_,l3_]:=
Module[{region,mesh,deformedMesh,deformedRegion,plot},
region=ParallelepipedGenerator[l1,l2,l3];
mesh=ToElementMesh[region,MaxCellMeasure->0.001];
deformedMesh=ToElementMesh["Coordinates"->Map[f,mesh["Coordinates"]],"MeshElements"->mesh["MeshElements"],
 "BoundaryElements"->mesh["BoundaryElements"], "PointElements"->mesh["PointElements"]];
deformedRegion=MeshRegion[deformedMesh];
Return[deformedRegion]
];

defPlate=DeformedPlateGenerator[6Pi/qx,7,0.7];
plate=RegionPlot3D[defPlate,
MeshShading->{{Automatic,None},{None,Automatic}},
Boxed->False,PlotStyle->Directive[Gray,Glow[],Opacity[0.2]]
(*EdgeForm[{Thin,Black}]]*)
];

defSlice=DeformedPlateGenerator[6Pi/qx,0.1,0.75];
slice=RegionPlot3D[defSlice,MeshShading->{{Automatic,None},{None,Automatic}},ColorFunction->Function[Directive[Opacity[StrainModulus[#1,#2]],Hue[NormalizedStrainWheel[#1,#2]]]],
ColorFunctionScaling->False,Boxed->False,Lighting->"Neutral"];

plateAndSlice=Show[plate,slice]

defSmallPlate=DeformedPlateGenerator[6Pi/qx,1.4,0.7];
smallPlate=RegionPlot3D[defSmallPlate,
MeshShading->{{Automatic,None},{None,Automatic}},
Boxed->False,PlotStyle->Directive[Gray,Glow[],Opacity[0.2]]
(*EdgeForm[{Thin,Black}]]*)
];

Show[smallPlate,slice,ViewPoint->Above]

sliceImage=Show[smallPlate,slice,ViewPoint->Above,ImageSize->Large]

(*Export[FileNameJoin[{NotebookDirectory[],"active-slice-HD.png"}],sliceImage,ImageResolution->300, Background->None]*)

defSliceShort=DeformedPlateGenerator[4Pi/qx,0.1,0.7];

sliceShort=RegionPlot3D[defSliceShort,
(*MeshShading->{{Automatic,None},{None,Automatic}},*)
ColorFunction->(ColorData["Rainbow",NormalizedStrainWheel[#1,#2]]&),ColorFunctionScaling->False,Boxed->True,Axes->False];

Show[sliceShort]

(*Export[FileNameJoin[{NotebookDirectory[],"bulk-wave-plate-slice.png"}],plateAndSlice,ImageResolution->300, Background->None];*)