#!/usr/bin/perl

use strict;
use warnings;
use Getopt::Long qw(:config no_ignore_case);
use Text::ASCIITable;
use Perun::Agent;
use Perun::Common qw(printMessage getSortingFunction tableContentToPrint);

sub help {
	return qq{
	Prints list of Members allowed on Resource. Resource is required field.
	----------------------------------------------------
	Available options:
	--resourceId  | -r  Resource idetifier
	--orderById   | -i  order by numeric ID
	--batch       | -b  batch
	--help        | -h  prints this help

	};
}

my ($resourceId, $batch, $sortingFunction);
GetOptions("help|h"  => sub {
		print help;
		exit 0;
	},
	"resourceId|r=i" => \$resourceId,
	"orderById|i"    => sub { $sortingFunction = getSortingFunction("getId") },
	#FIXME member nema getName ###     "orderByName|n" =>  sub {$sortingFunction = getSortingFunction("getName", 1) },
	"batch|b"        => \$batch) || die help;

#options check
unless (defined $sortingFunction) { $sortingFunction = getSortingFunction("getId", 1); }
unless (defined $resourceId) { die "ERROR: resourceId required\n";}

my $agent = Perun::Agent->new();
my $resourcesAgent = $agent->getResourcesAgent;
my @members = $resourcesAgent->getAllowedMembers( resource => $resourceId );
unless (@members) {
	printMessage "No Member found\n", $batch;
	exit 0;
}

#output

my @rows = ();
foreach my $member (sort $sortingFunction @members) {
	my $user = $agent->getUsersAgent->getUserByMember( member => $member->getId );
	my $name = $user->getFirstName." ".($user->getMiddleName ? $user->getMiddleName." " : "" ).$user->getLastName;
	my @row = ($member->getId, $name);
	push(@rows, \@row);
}

my @columnsNames = ('Id', 'Name');
print tableContentToPrint(\@columnsNames, \@rows, $batch);
